###Keyword###
ReDim

###Description###
Verändert die Größe eines bestehenden Arrays.

###Syntax###
<b>ReDim</b> $array<b>[</b>subscript 1<b>]</b>...<b>[</b>subscript n<b>]</b>

###Parameters###
@@ParamTable@@
$variable
	Die Name der zu verändernden Variable.
subscript
	Die Anzahl der Elemente, die in den einzelnen Arraydimensionen erstellt werden sollen; nummeriert von 0 bis n-1.
@@End@@


###Remarks###
Das Schlüsselwort ReDim ist ähnlich zu <a href="Dim.htm">Dim</a>, außer dass ReDim die Werte im Array nicht löscht, wenn die Arraygröße verändert wird. Die Anzahl der Dimensionen des Arrays muss dazu allerdings gleich bleiben. Das Array erhält den Gültigkeitsbereich (Glaobal oder Lokal), den es vor der Größenanpassung hatte.


###Related###
Dim, <a href="../functions/UBound.htm">UBound</a>


###Example###
; Beispiel zur Größenanpassung eines Arrays
Dim $I, $K, $T, $MSG
Dim $X[4][6], $Y[4][6]

For $I = 0 To 3
   For $K = 0 To 5
      $T = Int(Random(20) + 1)  ; Erzeugt zufällige Zahlen zwischen 1 und 20
      $X[$I][$K] = $T
      $Y[$I][$K] = $T
   Next
Next

ReDim $X[3][8]
Dim $Y[3][8]

$MSG = ""
For $I = 0 To UBound($X, 1) - 1
   For $K = 0 To UBound($X, 2) - 1
      If $K > 0 Then $MSG = $MSG & ", "
      $MSG = $MSG & $X[$I][$K]
   Next
   $MSG = $MSG & @CR
Next
MsgBox(0, "ReDim Demo", $MSG)

$MSG = ""
For $I = 0 To UBound($Y, 1) - 1
   For $K = 0 To UBound($Y, 2) - 1
      If $K > 0 Then $MSG = $MSG & ", "
      $MSG = $MSG & $Y[$I][$K]
   Next
   $MSG = $MSG & @CR
Next
MsgBox(0, "ReDim Demo", $MSG)
