# Funktionsreferenz

GUICtrlCreateIcon

Erstellt ein Icon für die GUI.

GUICtrlCreateIcon ( filename, iconID, left, top [, width [, height [, style [, exStyle]]]] )

Parameter

filename | Dateiname des Icons, das geladen werden soll.
iconID | Icon-Identifikationsnummer, wenn die Datei mehrere Icons enthält. Sonst -1.
left | Die linke Seite des Steuerelements. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet.
top | Die Oberkante des Steuerelements. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet.
width | [optional] Die Breite des Steuerelements (voreingestellt ist die zuvor verwendete Breite).
height | [optional] Die Höhe des Steuerelements (voreingestellt ist die zuvor verwendete Höhe).
style | [optional] Legt den Stil des Steuerelements fest. Siehe Appendix "GUI Control"-Stile. Standard ( -1) : $SS_NOTIFY Erzwungene Stile : $WS_TABSTOP, $SS_ICON
exStyle | [optional] Legt den erweiterten Stil des Steuerelements fest. Siehe Tabelle der erweiterten Stile.

Bemerkungen

Um Informationen im Steuerelement zu setzen oder zu verändern siehe GUICtrlSet....
Um das Icon zu verändern nachdem die Dialogbox angezeigt wird, verwende GUICtrlSetImage
Um weitere Stile zusätzlich zum Standardstil zu verwenden benutze BitOr($GUI_SS_DEFAULT_ICON, newstyle,...).

Siehe auch

GUICoordMode (Option), GUICtrlSetImage, GUICtrlSet..., GUIGetMsg

Beispiel

#include <GUIConstants.au3>
;example1 ---------------------------
GUICreate(" My GUI Icons")
$icon = GUICtrlCreateIcon ("shell32.dll",10, 20,20)
$icon2 = GUICtrlCreateIcon ("explorer.icl",10, 20,80)
$icon3 = GUICtrlCreateIcon ("explorer.icl",6, 80,80)
$n1=GUICtrlCreateIcon (@windowsdir & "\cursors\horse.ani",-1, 20,120,32,32)
$n2=GUICtrlCreateIcon ("shell32.dll",7 ,20,160,32,32)
GUISetState ()
; Run the GUI until the dialog is closed
While 1
$msg = GUIGetMsg()
If $msg = $GUI_EVENT_CLOSE Then ExitLoop
Wend
; example2 ---------------------------
Opt("GUICoordMode",1)
GUICreate("My GUI icon Race", 350,74,-1,-1)
GUICtrlCreateLabel ("", 331,0,1,74,5)
$n1=GUICtrlCreateIcon (@windowsdir & "\cursors\dinosaur.ani", -1, 0,0,32,32)
$n2=GUICtrlCreateIcon ( @windowsdir & "\cursors\horse.ani", -1, 0,40,32,32)
GUISetState (@SW_SHOW)
Dim $a = 0, $b = 0
While ($a < 300) And ($b < 300)
$a = $a + int(Random(0,1)+0.5)
$b = $b + int(Random(0,1)+0.5)
GUICtrlSetPos($n1, $a,0)
GUICtrlSetPos($n2, $b,40)
Sleep(20)
WEnd
sleep(1000)