# GUI Referenz - MessageLoop Modus

Im MessageLoop Modus wird dein Skript die meiste Zeit in einer engen Schleife verbringen. Diese Schleife wird einfach permanent die GUI mit der GUIGetMsg Funktion abfragen. Wenn ein Ereignis eingetreten ist, zeigt der Rückgabewert der GUIGetMsg Funktion die Details (ein Button wurde angeklickt, die GUI wurde geschlossen, etc.).

Der MessageLoop Modus ist der voreingestellte (default) Nachrichtenmodus für AutoIt GUIs - der andere mögliche Modus ist der OnEvent Modus.

Im MessageLoop Modus wirst du nur von Ereignissen erfahren während du aktiv die GUIGetMsg Funktion aufrufst; deshalb musst du dafür sorgen, dass du sie mehrmals pro Sekunde aufrufst, sonst wird deine GUI nicht reagieren.

## Grundlegendes MessageLoop Format

Der allgemeine MessageLoop Code siehst folgendermaßen aus:

While 1
$msg = GUIGetMsg()
...
...
WEnd

Normalerweise würde so eine Schleife die CPU zu 100% auslasten - glücklicherweise lässt die GUIGetMsg Funktion die CPU automatisch im Leerlauf laufen solange keine Ereignisse warten. Schreibe keinen sleep-Befehl in die Schleife aus Angst, die CPU auszulasten - das wird nur dazu führen, dass die GUI nicht mehr auf den Nutzer reagiert.

## GUI Events

Es gibt 3 Typen von Ereignis-Nachrichten, die GUIGetMsg zurückgeben kann:

- Kein Ereignis
- Control-Ereignis
- System-Ereignis

Kein Ereignis

Wenn keine Ereignisse darauf warten, verarbeitet zu werden, gibt GUIGetMsg den Wert 0 zurück. In einer normalen GUI ist das das häufigste Ereignis.

Control-Ereignis

Wenn ein Steuerelement angeklickt wird oder sein Wert verändert wird, wird ein Control-Ereignis gesendet - dieses Ereignis ist eine positive Zahl, die mit der control ID übereinstimmt, die beim Erstellen des Steuerelements mit GUICtrlCreate... zurückgegeben wurde.

System-Ereignis

System-Ereignisse - wie das Schließen der GUI - sind negative Zahlen. Die verschiedenen Ereignisse werden unten aufgelistet und sind in GUIConstants.au3 definiert:

$GUI_EVENT_CLOSE
$GUI_EVENT_MINIMIZE
$GUI_EVENT_RESTORE
$GUI_EVENT_MAXIMIZE
$GUI_EVENT_PRIMARYDOWN
$GUI_EVENT_PRIMARYUP
$GUI_EVENT_SECONDARYDOWN
$GUI_EVENT_SECONDARYUP
$GUI_EVENT_MOUSEMOVE

## Beispiel-GUI

Auf der Hauptseite der GUI Referenz haben wir mit einem einfachen "Hallo Welt!" Beispiel angefangen, das so aussah:

#include <GUIConstants.au3>
GUICreate("Hallo Welt", 200, 100)
GUICtrlCreateLabel("Hallo Welt! Wie geht's?", 30, 10)
GUICtrlCreateButton("OK", 70, 50, 60)
GUISetState(@SW_SHOW)
Sleep(2000)

Jetzt vervollständigen wir den Code mit einer MessageLoop und einigen der oben beschriebenenen Ereignis-Nachrichten (messages). Es ist üblich, wegen der Vielzahl der möglichen Nachrichten einen Select-Ausdruck der besseren Lesbarkeit wegen zu verwenden.

#include <GUIConstants.au3>
GUICreate("Hallo Welt", 200, 100)
GUICtrlCreateLabel("Hallo Welt! Wie geht's?", 30, 10)
$okbutton = GUICtrlCreateButton("OK", 70, 50, 60)
GUISetState(@SW_SHOW)
While 1
$msg = GUIGetMsg()
Select
Case $msg = $okbutton
MsgBox(0, "GUI Event", "Du hast auf OK geklickt!")
Case $msg = $GUI_EVENT_CLOSE
MsgBox(0, "GUI Event", "Du hast auf CLOSE geklickt! Programm wird beendet...")
ExitLoop
EndSelect
WEnd

So einfach ist das. Offensichtlich wird es umso komplizierter, je mehr Fenster und Steuerelemente du anlegst, aber das Beispiel zeigt dir die Grundlagen.

## GUIGetMsg für Fortgeschrittene und mehrere Fenster

Control-IDs sind eindeutig, auch wenn du mehrere Fenster hast; deshalb funktioniert der obenstehende Code gut mit Steuerelementen und mehreren Fenstern. Wenn du jedoch Ereignisse wie $GUI_EVENT_CLOSE oder $GUI_MOUSEMOVE verarbeiten willst, musst du wissen, welches GUI-Fenster das Ereignis ausgelöst hat. Dazu musst du GUIGetMsg folgendermaßen aufrufen:

$msg = GUIGetMsg(1)

Wenn die Funktion mit dem Parameter 1 aufgerufen wird, gibt sie statt dem Ereigniswert ein Array zurück, das das Ereignis ( in $array[0] ) und zusätzliche Information wie den Handle des Fensters beinhaltet ( in $array[1] ). Wenn im vorhergehenden Beispiel zwei Fenster angelegt worden wären, wäre die korrekte Schreibweise für den Code:

#include <GUIConstants.au3>
$mainwindow = GUICreate("Hallo Welt", 200, Wie geht's?", 30, 10)
$okbutton = GUICtrlCreateButton("OK", 70, 50, 60)
$dummywindow = GUICreate("Dummy-Fenster zum Testen ", 200, 100)
GUISwitch($mainwindow)
GUISetState(@SW_SHOW)
While 1
$msg = GUIGetMsg(1)
Select
Case $msg[0] = $okbutton
MsgBox(0, "GUI Event", "Du hast auf OK geklickt!")
Case $msg[0] = $GUI_EVENT_CLOSE And $msg[1] = $mainwindow
MsgBox(0, "GUI Event", "Du hast auf CLOSE im Hauptfenster geklickt! Programm wird beendet...")
ExitLoop
EndSelect
WEnd

Die erste große Änderung ist der Aufruf der GUISwitch Funktion - wenn ein neues Fenster angelegt wird, wird es das "default"-Fenster für zukünftige GUI-Operationen (einschließlich des Anlegens von Steuerelementen). In unserem Fall wollen wir mit dem Hauptfenster "Hello World" arbeiten, nicht mit dem Testfenster, deshalb schalten wir um ( "switch"). Manche GUI-Funktionen erlauben dir, den Fenster-Handle im Funktionsaufruf selbst zu benutzen - diese Funktionen werden also automatisch umschalten. In unserem Beispiel hätten wir das so machen können:

GUISetState(@SW_SHOW, $mainwindow)

Die zweite Änderung ist die Art, wie GUIGetMsg aufgerufen wird und wie die Ereignisse abgefragt werden - achte auf die Verwendung von $msg[0] und $msg[1] - jetzt wird das Skript nur beendet wenn das close-Ereignis gesendet wird und das Ereignis vom Hauptfenster stammt.