# Funktionsreferenz

GUICtrlSetResizing

Definiert die Methode zur Größenänderung, die von einem Steuerelement verwendet wird.

GUICtrlSetResizing ( controlID, resizing )

Parameter

controlID | Die Identifikationsnummer des Steuerelements (Control-ID), wie von einer GUICtrlCreate... Funktion zurückgegeben.
resizing | Siehe die untenstehende "Docking Values"-Tabelle, welche Werte verwendet werden können (falls nötig, werden mehrere Werte addiert).

Bemerkungen

Wenn ein GUI-Fenster in seiner Größe verändert wird, reagieren die darin enthaltenen Steuerelemente auf die Änderung - wie sie reagieren wird durch diese Funktion bestimmt. Um ein GUI-Fenster in der Größe verändern zu können, muss es mit den Stilen $WS_SIZEBOX und $WS_SYSMENU erzeugt worden sein. Siehe GUICreate.
"Docking Values"-Tabelle

Größenänderung | Wert | Keine Verschiebung ...
$GUI_DOCKLEFT | 2 | der linken Seite
$GUI_DOCKRIGHT | 4 | der rechten Seite
$GUI_DOCKHCENTER | 8 | der horizontalen Zentrierung
$GUI_DOCKTOP | 32 | der oberen Kante
$GUI_DOCKBOTTOM | 64 | der unteren Kante
$GUI_DOCKVCENTER | 128 | der vertikalen Zentrierung
$GUI_DOCKWIDTH | 256 | Breite wird nicht verändert
$GUI_DOCKHEIGHT | 512 | Höhe wird nicht verändert
$GUI_DOCKSIZE | 768 | Größe wird nicht verändert (256+512)
$GUI_DOCKMENUBAR | 544 | 512+32: das Steuerelement bleibt am oberen Rand des Fensters und ändert seine Höhe nicht.
$GUI_DOCKSTATEBAR | 576 | 512+64: das Steuerelement bleibt am unteren Rand des Fensters und ändert seine Höhe nicht.
$GUI_DOCKALL | 802 | 2+32+256+512: das Steuerelement verschiebt sich durch die Größenänderung nicht.

Siehe auch

Keine.

Beispiel

#include <GUIConstants.au3>
Opt("GUICoordMode", 2)
GUICreate ("My InputBox",190,114,-1,-1,$WS_SIZEBOX+$WS_SYSMENU) ; start the definition
GUISetIcon ("Eiffel Tower.ico")
GUISetFont (8,-1,"Arial")
GUICtrlCreateLabel ("Prompt", 8,7) ; add prompt info
GUICtrlSetResizing (-1,$GUI_DOCKLEFT+$GUI_DOCKTOP)
$nEdit = GUICtrlCreateInput ("Default", -1,3,175,20,$ES_PASSWORD) ; add the input area
GUICtrlSetState ($nEdit,$GUI_FOCUS)
GUICtrlSetResizing ($nEdit,$GUI_DOCKBOTTOM+$GUI_DOCKHEIGHT)
$nOk = GUICtrlCreateButton ("OK",-1,3,75,24) ; add the button that will close the GUI
GUICtrlSetResizing ($nOk,$GUI_DOCKBOTTOM+$GUI_DOCKSIZE+$GUI_DOCKVCENTER)
$nCancel = GUICtrlCreateButton ("Annuler", 25,-1) ; add the button that will close the GUI
GUICtrlSetResizing ($nCancel,$GUI_DOCKBOTTOM+$GUI_DOCKSIZE+$GUI_DOCKVCENTER)
GUISetState () ; to display the GUI
; Run the GUI until the dialog is closed
While 1
$msg = GUIGetMsg()
If $msg = $GUI_EVENT_CLOSE Then ExitLoop
Wend