Funktionsreferenz

GUICtrlCreateDate

Erstellt ein Datumsauswahl-Element für die GUI.

GUICtrlCreateDate ( "text", left, top [, width [, height [, style [, exStyle]]]] )

 

Parameter

text Das voreingestellte Datum.
left Die linke Seite des Steuerelements. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet.
top Die Oberkante des Steuerelements. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet.
width [optional] Die Breite des Steuerelements (voreingestellt ist die zuvor verwendete Breite).
height [optional] Die Höhe des Steuerelements (voreingestellt ist die zuvor verwendete Höhe).
style [optional] Legt den Stil des Steuerelements fest. Siehe Appendix "GUI Control"-Stile.

Standard (-1) : $DTS_LONGDATEFORMAT
Erzwungener Stil : $WS_TABSTOP
exStyle [optional] Legt den erweiterten Stil des Steuerelements fest. Siehe Tabelle der erweiterten Stile.

 

Bemerkungen

Um den Wert des Steuerelements zu erhalten siehe GUICtrlRead.
Um Informationen im Steuerelement zu setzen oder zu verändern siehe GUICtrlSet....

Um weitere Stile zusätzlich zum Standardstil zu verwenden benutze BitOr($GUI_SS_DEFAULT_DATE, newstyle,...).

 

Siehe auch

GUICoordMode (Option), GUICtrlSetState, GUIGetMsg, GUICtrlRead

 

Beispiel


#include <GUIConstants.au3>

; example1
GUICreate ( "My GUI get date", 200,200,800,200)
$date=GUICtrlCreateDate ("1953/04/25", 10,10,185,20 )
GUISetState ()

; Run the GUI until the dialog is closed
Do
    $msg = GUIGetMsg()
Until $msg = $GUI_EVENT_CLOSE

MsgBox(0,"Date",GUICtrlRead($date))
GUIDelete()

; example2
$DTS_TIMEFORMAT = 9
GUICreate("My GUI get time")
$n=GUICtrlCreateDate ( "", 20, 20, 100, 20, $DTS_TIMEFORMAT)
GUISetState ()

; Run the GUI until the dialog is closed
Do
    $msg = GUIGetMsg()
Until $msg = $GUI_EVENT_CLOSE

MsgBox(0,"Time", GUICtrlRead($n))