Funktionsreferenz

GUICtrlCreateList

Erstellt ein Listen-Steuerelement für die GUI.

GUICtrlCreateList ( "text", left, top [, width [, height [, style [, exStyle]]]] )

 

Parameter

text Der Text in der Liste.
left Die linke Seite des Steuerelements. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet.
top Die Oberkante des Steuerelements. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet.
width [optional] Die Breite des Steuerelements (voreingestellt ist die zuvor verwendete Breite).
height [optional] Die Höhe des Steuerelements (voreingestellt ist die zuvor verwendete Höhe).
style [optional] Legt den Stil des Steuerelements fest. Siehe Appendix "GUI Control"-Stile.

Standard ( -1) : $LBS_SORT, $WS_BORDER, $WS_VSCROLL, $LBS_NOTIFY
Erzwungene Stile : $WS_TABSTOP
exStyle [optional] Legt den erweiterten Stil des Steuerelements fest. Siehe Tabelle der erweiterten Stile.

 

Bemerkungen

Um den Wert des Steuerelements zu erhalten siehe GUICtrlRead.
Um Informationen im Steuerelement zu setzen oder zu verändern siehe GUICtrlSet....

Die verschiedenen Listeneinträge, aus denen der Nutzer auswählen kann, können mit GUICtrlSetData gesetzt werden.

Um das Scrollen in horizontaler Richtung zu beschränken verwendest du GUICtrlSetLimit

Um weitere Stile zusätzlich zum Standardstil zu verwenden benutze BitOr($GUI_SS_DEFAULT_LIST, newstyle,...).

 

Siehe auch

GUICoordMode (Option), GUICtrlSetData, GUICtrlSetLimit, GUICtrlSet..., GUIGetMsg

 

Beispiel


#include <GUIConstants.au3>

GLOBAL $MESSAGE = "The following buttons have been clicked"
GUICreate("My GUI list") ; will create a dialog box that when displayed is centered

$add=GUICtrlCreateButton ("Add", 64,32,75,25)
$clear=GUICtrlCreateButton ("Clear", 64,72,75,25)
$mylist=GUICtrlCreateList ("buttons that have been clicked", 176,32,121,97)
GUICtrlSetLimit(-1,200) ; to limit horizontal scrolling
GUICtrlSetData(-1,$MESSAGE)
$close=GUICtrlCreateButton ("my closing button", 64,160,175,25)

GUISetState ()

$msg = 0
While $msg <> $GUI_EVENT_CLOSE
    $msg = GUIGetMsg()

    Select
         case $msg = $add
        GUICtrlSetData($mylist,"You clicked button No1|")
         case $msg = $clear
        GUICtrlSetData($mylist,"")
         Case $msg = $close
            MsgBox(0,"", "the closing button has been clicked",2)
            Exit
    EndSelect
Wend