Funktionsreferenz

GUICtrlCreateTab

Erstellt eine Registerkartengruppe für die GUI.

GUICtrlCreateTab ( left, top [, width [, height [, style [, exStyle]]]] )

 

Parameter

left Die linke Seite des Steuerelements. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet.
top Die Oberkante des Steuerelements. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet.
width [optional] Die Breite des Steuerelements (voreingestellt ist die zuvor verwendete Breite).
height [optional] Die Höhe des Steuerelements (voreingestellt ist die zuvor verwendete Höhe).
style [optional] Legt den Stil des Steuerelements fest. Siehe Appendix "GUI Control"-Stile.

Standard ( -1) : Keine.
Erzwundene Stile : $WS_TABSTOP, $WS_CLIPSIBLINGS
exStyle [optional] Legt den erweiterten Stil des Steuerelements fest. Siehe Tabelle der erweiterten Stile.

 

Bemerkungen


Dieses Steuerelement ist einfach ein Control, in dem die Registerkarten (Tabitem-Controls) erzeugt werden; danach werden bestimmte Steuerelemente mit GUICtrlCreate... den einzelnen Registerkarten hinzugefügt.

Um Informationen im Steuerelement zu setzen oder zu verändern siehe GUICtrlSet....

Um weitere Stile zusätzlich zum Standardstil zu verwenden benutze BitOr($GUI_SS_DEFAULT_TAB, newstyle,...).

 

Siehe auch

GUICtrlCreateTabItem, GUICoordMode (Option), GUICtrlSet..., GUIGetMsg

 

Beispiel


#include <GUIConstants.au3>

GUICreate("My GUI Tab")  ; will create a dialog box that when displayed is centered

GUISetBkColor(0x00E0FFFF)
GUISetFont(9, 300)

$tab=GUICtrlCreateTab (10,10, 200,100)

$tab0=GUICtrlCreateTabitem ("tab0")
GUICtrlCreateLabel ("label0", 30,80,50,20)
$tab0OK=GUICtrlCreateButton ("OK0", 20,50,50,20)
$tab0input=GUICtrlCreateInput ("default", 80,50,70,20)

$tab1=GUICtrlCreateTabitem ( "tab----1")
GUICtrlCreateLabel ("label1", 30,80,50,20)
$tab1combo=GUICtrlCreateCombo ("", 20,50,60,40)
GUICtrlSetData(-1,"Trids|CyberSlug|Larry|Jon|Tylo", "Jon") ; default Jon
$tab1OK=GUICtrlCreateButton ("OK1", 80,50,50,20)

$tab2=GUICtrlCreateTabitem ("tab2")
GUICtrlSetState(-1,$GUI_SHOW)   ; will be display first
GUICtrlCreateLabel ("label2", 30,80,50,20)
$tab2OK=GUICtrlCreateButton ("OK2", 140,50,50)

GUICtrlCreateTabitem ("")   ; end tabitem definition

GUICtrlCreateLabel ("label3", 20,130,50,20)

GUISetState ()

; Run the GUI until the dialog is closed
While 1
    $msg = GUIGetMsg()
   
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
Wend